Un "jeu" avec des boutons

J-M-L · November 9, 2024, 6:46pm

Pour répondre à la demande de @BenjiBLC (Choix aléatoire parmi des led sélectionnées)

je me suis amusé à coder son petit jeu.

le jeu démarre en mode sélection : on appuie sur les boutons des positions que l'on veut sélectionner, la LED s'allume en conséquence.

On appuie alors sur le bouton Start, les Leds s'éteignent et une led aléatoire dans la liste de celles qui avaient été sélectionnées s'allumera pendant 1 seconde (on peut changer cela dans la constante intervalle). La même position peut s'allumer plusieurs fois de suite car le tirage est aléatoire sans mémoire.

Si on appuie sur reset, le jeu revient en mode sélection.

c'est testable ici:

J'ai pris une MEGA pour avoir plein de broches dispos. Attention les LEDs ça consomme du courant... J'ai mis des résistances de limitation de courant à 470Ω dans le schéma pour minimiser le courant tiré sur chaque broche à ~10mA max. Donc même si les 9 Leds sont allumées on reste dans une enveloppe raisonnable pour la capacité du processeur. Cela veut dire que les Leds ne seront pas aussi brillantes que si plus de courant pouvait circuler dedans. Mais pour cela il faudrait un étage de puissance pour contrôler ces LEDs (replacer la résistance + LED par un montage à base de relai, transistor, MOSFET, ... qui alimentera la vraie lampe sans tirer trop de courant )

le code


/* ============================================
  code is placed under the MIT license
  Copyright (c) 2024 J-M-L
  For the Arduino Forum : https://forum.arduino.cc/u/j-m-l

  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files (the "Software"), to deal
  in the Software without restriction, including without limitation the rights
  to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  copies of the Software, and to permit persons to whom the Software is
  furnished to do so, subject to the following conditions:

  The above copyright notice and this permission notice shall be included in
  all copies or substantial portions of the Software.

  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
  THE SOFTWARE.
  ===============================================
*/

/*

  Mega pin 2 <---> bouton start <---> Mega GND
  Mega pin 3 <---> bouton reset <---> Mega GND

  Mega pin 4 <---> R 470Ω <---> (anode) LED 1 (celle de droite) (cathode) <---> Mega GND
  Mega pin 5 <---> R 470Ω <---> (anode) LED 2 (cathode) <---> Mega GND
  Mega pin 6 <---> R 470Ω <---> (anode) LED 3 (cathode) <---> Mega GND
  Mega pin 7 <---> R 470Ω <---> (anode) LED 4 (cathode) <---> Mega GND
  Mega pin 8 <---> R 470Ω <---> (anode) LED 5 (cathode) <---> Mega GND
  Mega pin 9 <---> R 470Ω <---> (anode) LED 6 (cathode) <---> Mega GND
  Mega pin 10 <---> R 470Ω <---> (anode) LED 7 (cathode) <---> Mega GND
  Mega pin 11 <---> R 470Ω <---> (anode) LED 8 (cathode) <---> Mega GND
  Mega pin 12 <---> R 470Ω <---> (anode) LED 9 (celle de gauche) (cathode) <---> Mega GND

  Mega pin 14 <---> bouton 9 (celui de gauche) <---> Mega GND
  Mega pin 15 <---> bouton 8 <---> Mega GND
  Mega pin 16 <---> bouton 7 <---> Mega GND
  Mega pin 17 <---> bouton 6 <---> Mega GND
  Mega pin 18 <---> bouton 5 <---> Mega GND
  Mega pin 19 <---> bouton 4 <---> Mega GND
  Mega pin 20 <---> bouton 3 <---> Mega GND
  Mega pin 21 <---> bouton 2 <---> Mega GND
  Mega pin 22 <---> bouton 1 (celui de droite) <---> Mega GND

*/


#include <Toggle.h>

class BoutonLed {
  private:
    const byte pinLed;
    const byte pinBouton;
    Toggle bouton;

  public:
    BoutonLed(const byte pinLed, const byte pinBouton) : pinLed(pinLed), pinBouton(pinBouton), bouton(pinBouton) {}

    void begin() {
      pinMode(pinLed, OUTPUT);
      bouton.begin(pinBouton);
    }

    void allumer() {
      digitalWrite(pinLed, HIGH);
    }

    void eteindre() {
      digitalWrite(pinLed, LOW);
    }

    void inverser() {
      digitalWrite(pinLed, digitalRead(pinLed) == HIGH ? LOW : HIGH);
    }

    bool estActive() {
      return digitalRead(pinLed) == HIGH;
    }

    void miseAJour() {
      bouton.poll();
      if (bouton.onPress()) inverser();
    }
};

BoutonLed boutonLeds[] = {
  {12, 14}, {11, 15}, {10, 16},
  { 9, 17}, { 8, 18}, { 7, 19},
  { 6, 20}, { 5, 21}, { 4, 22}
};
const byte nbLeds = sizeof boutonLeds / sizeof * boutonLeds;

BoutonLed * selection[nbLeds];
byte nbLedsSelection = 0;
unsigned long chrono;
const unsigned long intervalle = 1000ul;

const byte pinBoutonStart = 2;
const byte pinBoutonReset = 3;
Toggle boutonStart, boutonReset;

enum : byte {SELECTION, ANIMATION} mode = SELECTION;

void eteindre() {
  for (auto &bl : boutonLeds) bl.eteindre();
}

void reset() {
  eteindre();
  nbLedsSelection = 0;
  mode = SELECTION;
}

void animation() {
  if (nbLedsSelection == 0) return;
  if (millis() - chrono >= intervalle) {
    byte prochainChoix = random(nbLedsSelection);
    eteindre();
    selection[prochainChoix]->allumer();
    chrono = millis();
  }
}

void setup() {
  randomSeed(analogRead(A0));
  boutonStart.begin(pinBoutonStart);
  boutonReset.begin(pinBoutonReset);
  for (auto &bl : boutonLeds) bl.begin();
  Serial.begin(115200);
}

void loop() {
  boutonReset.poll();
  if (boutonReset.onPress()) reset();

  switch (mode) {
    case SELECTION:
      boutonStart.poll();
      if (boutonStart.onPress()) {
        nbLedsSelection = 0;
        for (auto &bl : boutonLeds)
          if (bl.estActive()) selection[nbLedsSelection++] = &bl;
        chrono = millis();
        mode = ANIMATION;
      } else {
        for (auto &bl : boutonLeds) bl.miseAJour();
      }
      break;

    case ANIMATION:
      animation();
      break;
  }
}

les connexions sont les suivantes :

Mega pin 2 <---> bouton start <---> Mega GND
Mega pin 3 <---> bouton reset <---> Mega GND

Mega pin 4 <---> R 470Ω <---> (anode) LED 1 (celle de droite) (cathode) <---> Mega GND
Mega pin 5 <---> R 470Ω <---> (anode) LED 2 (cathode) <---> Mega GND
Mega pin 6 <---> R 470Ω <---> (anode) LED 3 (cathode) <---> Mega GND
Mega pin 7 <---> R 470Ω <---> (anode) LED 4 (cathode) <---> Mega GND
Mega pin 8 <---> R 470Ω <---> (anode) LED 5 (cathode) <---> Mega GND
Mega pin 9 <---> R 470Ω <---> (anode) LED 6 (cathode) <---> Mega GND
Mega pin 10 <---> R 470Ω <---> (anode) LED 7 (cathode) <---> Mega GND
Mega pin 11 <---> R 470Ω <---> (anode) LED 8 (cathode) <---> Mega GND
Mega pin 12 <---> R 470Ω <---> (anode) LED 9 (celle de gauche) (cathode) <---> Mega GND

Mega pin 14 <---> bouton 9 (celui de gauche) <---> Mega GND
Mega pin 15 <---> bouton 8 <---> Mega GND
Mega pin 16 <---> bouton 7 <---> Mega GND
Mega pin 17 <---> bouton 6 <---> Mega GND
Mega pin 18 <---> bouton 5 <---> Mega GND
Mega pin 19 <---> bouton 4 <---> Mega GND
Mega pin 20 <---> bouton 3 <---> Mega GND
Mega pin 21 <---> bouton 2 <---> Mega GND
Mega pin 22 <---> bouton 1 (celui de droite) <---> Mega GND

jef59 · November 10, 2024, 4:23am

Bonjour,

Jolie réalisation!

On peut, comme vous l'indiquez, insérer facilement un étage de "puissance" tout câblé de type ULN28003 de ce type:

UN DES NOMBREUX MODULES ULN

Avec ce module, vous pouvez séparer l'alimentation du MEGA de l'alimentation des LEDs, ou pas.

Le courant consommé sur chaque sortie MEGA pour piloter une LED serait de l'ordre de 1,4mA, et celui traversant les LEDs serait fixé par les résitances en série avec chaque LED.

L'avantage de ce module est entre autre sa simplicité de câblage, 1 module permet de piloter 8 LEDs, vous pouvez en mettre plusieurs.

Ce module peut s'alimenter jusque 50V.

L'idéal est de rajouter à cela une alimentation compatible à l'alimentation du MEGA (7 à 12V) et de s'en servir aussi pour alimenter les LEDs.

(je n'ai pas mon PC sous la main pour faire le schéma du rajout de cet étage de puissance).

L'idée, c'est ça:

J-M-L · November 10, 2024, 6:40am

Effectivement un ULN2803 peut convenir pour piloter des LED

Si ce sont des petites leds qui nécessitent dans les 20 mA, il est un peu surdimensionné pour cette tâche ( chaque canal de l’ULN2803 peut supporter jusqu’à 500 mA - c’est pour cela que ce type de composant est plus souvent utilisé pour piloter des charges plus lourdes, comme des relais ou des moteurs de petite taille).

Si ce sont des petites LEDs je pensais plus à des transistors NPN individuels ou des circuits intégrés spécialisés pour la commande de LED, comme le TLC5940 ou le MAX7219 si besoin de contrôle PWM.

La bonne solution c’est sans doute d’utiliser le composant dont on dispose déjà dans le tiroir « des bidules à utiliser un jour » (et c’est vrai que des ULN2803 on en a souvent)

jpbbricole · November 10, 2024, 8:32am

Bonjour J-M-L

A partir d'un certain nombre de LED, ne serais ce pas plus pratique du voir du côté des LED adressables, ça simplifierai le câblage et ça augmente les possibilités

Ces LED devraient aussi faire partie de:

Bon dimanche!
jpbbricole

J-M-L · November 10, 2024, 9:03am

Tout à fait. Je n'ai pas mis de Leds adressables car @BenjiBLC ne le souhaitait pas dans son post d'origine, mais je pense que ce serait une bonne idée - en plus on pourrait facilement avoir plusieurs LEDs par enfant, même un cercle lumineux autour de leur position

Topic		Replies	Views
Comment contrôler plus de 400 LED Français	18	2906	May 6, 2021
[debutant] gestion blink led ws2812 Français	10	1441	September 25, 2021
4 leds aléatoires avec la fonction millis Français	35	659	January 18, 2024
Petit jeu avec des Leds et un bouton Réalisations et Projets Finis	10	3513	May 7, 2021
[Conseil] Table leds rgb 16x16 tactile pilotée par le port série Français	1	1096	May 6, 2021

Un "jeu" avec des boutons

Related topics