Sound sensor problems

[evanz2114]

Hi! I am currently working on my project which is a library noise monitor. The problem is that I think the sound sensor module is not detecting accurate noise on surroundings unless its near the microphone. The system is meant to have 3 levels of noise 'quite, moderate, and loud' and has a corresponding alarm. I think the sensor is detecting the alarm and its stuck on the loud level. I don't know how to fix it or whats the main problem given I don't have much background in this. Hope you can give advices

Here's the code:

int soundSensor = A0;

int greenLED = 6;
int yellowLED = 7;
int redLED = 8;
int buzzer = 9;


int lowThreshold = 120;
int highThreshold = 250;

void setup() {
  pinMode(greenLED, OUTPUT);
  pinMode(yellowLED, OUTPUT);
  pinMode(redLED, OUTPUT);
  pinMode(buzzer, OUTPUT);
  Serial.begin(9600);
}

void loop() {

  // 🔹 AVERAGING (makes readings stable)
  int total = 0;
  for (int i = 0; i < 10; i++) {
    total += analogRead(soundSensor);
    delay(5);
  }

  int soundValue = total / 10;

  // 🔹 BOOST sensitivity (for weak sensors)
  soundValue = soundValue * 2;

  Serial.println(soundValue);

  //  QUIET
  if (soundValue < lowThreshold) {
    digitalWrite(greenLED, HIGH);
    digitalWrite(yellowLED, LOW);
    digitalWrite(redLED, LOW);
    digitalWrite(buzzer, LOW);
  }

  // MODERATE
  else if (soundValue >= lowThreshold && soundValue < highThreshold) {
    digitalWrite(greenLED, LOW);
    digitalWrite(redLED, LOW);

    digitalWrite(yellowLED, HIGH);
    digitalWrite(buzzer, HIGH);
    delay(300);

    digitalWrite(yellowLED, LOW);
    digitalWrite(buzzer, LOW);
    delay(500);
  }

  // LOUD 
  else {
    digitalWrite(greenLED, LOW);
    digitalWrite(yellowLED, LOW);

    digitalWrite(redLED, HIGH);
    digitalWrite(buzzer, HIGH);
    delay(120);

    digitalWrite(redLED, LOW);
    digitalWrite(buzzer, LOW);
    delay(180);
  }
}

[UKHeliBob]

Your other topic on the same subject deleted.

Please do not duplicate your questions as doing so wastes the time and effort of the volunteers trying to help you as they are then answering the same thing in different places.

Please create one topic only for your question and choose the forum category carefully. If you have multiple questions about the same project then please ask your questions in the one topic as the answers to one question provide useful context for the others, and also you won’t have to keep explaining your project repeatedly.

Repeated duplicate posting could result in a temporary or permanent ban from the forum.

Could you take a few moments to Learn How To Use The Forum

How to get the best out of this forum

See also FAQ - Arduino Forum for general rules on forum behavior and etiquette. Hello, Welcome to the Arduino Forum. This guide explains how to get the best out of this forum. Please read and follow the instructions below. Being new here you might think this is having rules for the sake of rules, but that is not the case. If you don’t follow the guidelines all that happens is there is a long exchange of posts while we try to get you to tell us what we need in order to help you, which is frus…

It will help you get the best out of the forum in the future.

Thank you.

[xfpd]

@evanz2114

I think the sensor is detecting the alarm

Remove the alarm.

[jim-p]

The microphone module you have does not have an amplifier so they are not very sensitive to sounds. You need to get close and yell into them to see any measurable output.
Buy a microphone module that has an amplifier on the module.

[Ron_Blain]

You have chosen a good project. However I agree strongly with jim-p in that to detect low level sound as in a library you will need a very good sensor. Based on your image I will guess you are using one of these or similar. That is hardly going to work for your application. A good microphone for detecting low level sound is expensive.

Next, I suggest you gain a good understanding of sound as measured in dba (decibels audio) . Then learn how fast sound decreases with distance. A decent sound meter cost well over $200 USD which gives you an idea of what’s involved in sound measurement.

I am not trying to dissuade you from this project but merely pointing out how important it is to understand what you wish to measure.

Ron

[xfpd]

I think we all made this inexpensive project early in electronics: Big Ear Amplifier

[Ron_Blain]

I think we all made this inexpensive project early in electronics: Big Ear Amplifier

OMG, I built one of those big ears as a kid. I put a cone on my microphone to make it directional. It was raining outside and I pointed it at a puddle. The actual sound of the rain drops splashing in the puddle was incredible. That had to be early 60s. Thanks for that memory.

Ron

[Brazilino]

You may want to take a look at the topic below.

Classroom noise detector

I came across this thread some days ago and I found the proposed project interesting, especially because I also have teachers in my family and friends. I decided trying to build the project just for fun and see what could be done. I used a MAX4466 module and a 10 segment LED bar graph instead of the WS2812 ring, since I had none with me. [image] At this point, I was asking myself if it is really a good idea to have flashing lights in a class with ADHD kids. I also used a Nano V3 clone, and …

I liked the sensor I have used (MAX4466), although my idea was to measure noise in a classroom (thus much more noisy than a library).

I believe it will be hard to get whispers from a far distance with a cheapo sensor.

EDIT: fixed linked topic

[tigger]

Sparkfun do a Sound Detector module which might be worth a look.
Must admit, I didn't have a lot of success with it (trying to pick up the sound of a contactor on an electricity utility meter time switch).
Tried quite a few things, cone, sound-proofing the meter box.

[jim-p]

This module will work much bettor

MAX4466 Microphone Preamplifier Module - ProtoSupplies

[Wawa]

@evanz2114

int lowThreshold = 120;
int highThreshold = 250;

Not the way I would do things.
I would dynamically measure the difference between high and low peaks and then use a single threshold value.
Like this (untested)

const byte soundPin = A0;
int rawValue, minPeak, maxPeak; // peak values
unsigned long startMillis;

void setup() {
  Serial.begin(115200);
}

void loop() {
  maxPeak = 0; // reset
  minPeak = 1023; // reset
  startMillis = millis(); // mark
  while (millis() - startMillis < 250) { // sampling time
    rawValue = analogRead(soundPin); // get samples
    if (rawValue > maxPeak) maxPeak = rawValue;
    if (rawValue < minPeak) minPeak = rawValue;
  }
  rawValue = maxPeak - minPeak; // final peak to peak value
  Serial.println(rawValue); // see what values you're getting first
  // LED code here
}