How to Wire and Program a Button

[DaveX]

How to Wire and Program a Button

This thread is about the built-in example "How to Wire and Program a Button" tutorial and its Button.ino code.

/*
  Button

  Turns on and off a light emitting diode(LED) connected to digital pin 13,
  when pressing a pushbutton attached to pin 2.

  The circuit:
  - LED attached from pin 13 to ground through 220 ohm resistor
  - pushbutton attached to pin 2 from +5V
  - 10K resistor attached to pin 2 from ground

  - Note: on most Arduinos there is already an LED on the board
    attached to pin 13.

  created 2005
  by DojoDave <http://www.0j0.org>
  modified 30 Aug 2011
  by Tom Igoe

  This example code is in the public domain.

  https://www.arduino.cc/en/Tutorial/BuiltInExamples/Button
*/

// constants won't change. They're used here to set pin numbers:
const int buttonPin = 2;  // the number of the pushbutton pin
const int ledPin = 13;    // the number of the LED pin

// variables will change:
int buttonState = 0;  // variable for reading the pushbutton status

void setup() {
  // initialize the LED pin as an output:
  pinMode(ledPin, OUTPUT);
  // initialize the pushbutton pin as an input:
  pinMode(buttonPin, INPUT);
}

void loop() {
  // read the state of the pushbutton value:
  buttonState = digitalRead(buttonPin);

  // check if the pushbutton is pressed. If it is, the buttonState is HIGH:
  if (buttonState == HIGH) {
    // turn LED on:
    digitalWrite(ledPin, HIGH);
  } else {
    // turn LED off:
    digitalWrite(ledPin, LOW);
  }
}

Wokwi simulation: ArduinoBIE_HowToWireAndProgramAButton

Per these posts and these guidelines, if you've got something to say about the example, its schematics, its explanation, or you have a better way of doing it, please share.

[DaveX]

I thought @LarryD's diagram about wiring was good:

Push Button Wiring official guide question

There's a schematic demonstrating the several ways to wire the button and ranks the options: [image] Does someone have the canonical link to this diagram and any discussion around it? (ETA: Share tips you have come across - #999 by LarryD -- There's some discussion there and at https://forum.arduino.cc/t/wiring-a-button-pull-down-bad-vs-input-pullup-best/116298566 ) The Arduino tutorial chooses the BAD S1 wiring: [image] The danger I see in th…

Wokwi - Online ESP32, STM32, Arduino Simulator

Also:

@DaveX

And yes, a four-wire, two-terminal device adds ambiguity to the learning process.

Hooking from led - avoid the dim - #15 by ruilviana had a good image:

And there are good references at

• Gammon Forum : Electronics : Microprocessors : Switches tutorial -- @nickgammon on the differences, software and hardware debouncing. Shows an oscilloscope plot of debouncing an Uno with 1uF capacitor for a 36ms response.
• https://www.ganssle.com/debouncing-pt2.htm -- Jack Ganssle on the details of debouncing. (part 1 on bouncing with lots of plots of different switches.)
• Using Digital Inputs -- switches & buttons @johnerrington on the behavior of digital inputs
• Switch bounce and solutions to it by @johnerrington.

Also, there is a completely different example for INPUT_PULLUP wiring:

https://docs.arduino.cc/built-in-examples/digital/InputPullupSerial/

ArduinoBIE_DigitalInputPullup - Wokwi ESP32, STM32, Arduino Simulator

[DaveX]

Now it is discoverable on the forum if you type the name of the tutorial into the search box:

I might rearrange the OP to make the displayed blurb more on-point.

... like:

[GolamMostafa]

You have been asked by yourself to draw a connection diagram among DPIn-2 of UNO, Switch, Pull-down resistor, 5V, and GND. I think that you are missing two more items which are: a LED with a series resistor, which will turn On when the Switch is pressed and Serial Monitor to display this message: **Switch has been pressed". After that you have to create a sketch to check that the Switch is closed.

1. My version of diagram is depicted in Fig-1:

Figure-1:

2. My Sketch to check that Switch has been pressed and then turn On LED1 and show this message on SM (Srial Monitor: Swicth has been pressed.

(1) Activate Serial Monitor at Bd = 9600.
Serial.begin(9600);

(2) Set direction of DPin-2 as INPUT with external pull-down resistor and DPin-4 as OUTPUT.

pinMode(2, INPUT);
pinMode(4, OUTPUT);

(3) Check again and again that Switch has been pressed/closed by looking for HIGH at DPin-2. If Switch is closed, turn On LED1 and show message on SM.

int y = digitalRead(2);
if( y != HIGH)
{
   Check again for closed condition of Switch //convert this Text Code into C++/Arduino Code
}
delay(200);  //wait for the debouncing of Switch
digitalWrite(4, HIGH); //LED1 is ON
Serial.println("Switch has been pressed.")

3. Click on Arduino icon and check check that a window (called IDE = Integrated Development environment) has apperaed on the Desktop of the PC with the following two empty functions:

void setup()
{

}

void loop()
{

}

4. Place the codes of Step-2 within the appropriate function(s) of Step-3.
5. Verify/Compile to eliminate erros of the sketch.
6. Upload the sketch.
7. Open the SM at Bd (Baud rate) = 9600 (Fig-2).
8. Gently, just press/release the switch.
9. Observe that LED1 has turned On.
10. Check that Swicth has been pressed message has appeared on SM.

Figure-2:

[DaveX]

A small mismatch between the code and the diagrams is that the code calls out an external LED, while the circuit diagram uses the Uno's built-in LED (attached to 13, LED_BUILTIN, or PB5) instead of an external LED.

https://docs.arduino.cc/hardware/uno-rev3

[gilshultz]

Over the years I have learned the hard way bringing the Processor power into the outside world can give you endless grief. It is a great antenna.

[alto777]

@DaveX

if you've got something to say about the example

I don't like that the leading example is in terms of switches that are pulled low.

I could say honestly I don't like that LEDs are almost always wired to ground and illuminate with HIGH.

I don't like HIGH and LOW, but we are stuck with that, please don't spend time, anyone, 'splaining why it's a Good Thing.

So my point is that the earlier ppl can be turned on to the fact that sometime grounding a pin can make an LED light up, and sometimes pushing a button means the input reads HIGH and that…

… fixing this kind of upside down problem is always always going to be handy.

the better. Sorry, my grammar is out to lunch.

At an early point with the kinds of things noobs get up to with Arduino boards, some kind of minimal understanding of the real works to which we like to connect is essential.

Just a small bit of Boy Scout merit badge electronics.

a7

[DaveX]

I think the next step up from from How to Wire and Program a Button example is the State Change Detection (edge detection) for pushbuttons example.

Maybe this thread would be useful:

State Change Detection (Edge Detection) for pushbuttons

This thread is about the built-in example "State Change Detection (Edge Detection) for pushbuttons" tutorial and the diagram and StateChangeDetection.ino code it offers: [image] /* State change detection (edge detection) Often, you don't need to know the state of a digital input all the time, but you just need to know when the input changes from one state to another. For example, you want to know when a button goes from OFF to ON. This is called state change detection, or edge det…

Here's another button-testing sketch with some rate-limited scanning of all the (floating) inputs :

// report.ino -- A demo of millis-based periodic status reporting
// https://wokwi.com/projects/408753591671265281
//
//  Every 1000ms, this program reads and reports the analog and digital staus of each pin.
//

// configure pullup resistors? zero means floating, non-zero means pullup
const int pullup[] = {0, 0,            // RX,TX on Uno
                      0, 0, 0,         // 2,3,4
                      0, 0, 0, 0, 0,   // 5-9
                      0, 0, 0, 0,      // 10,11,12,13
                      0, 0, 0, 0, 0, 0 // A0, A1 A2 A3 A4 A5
                     };

void setup() {
  Serial.begin(115200);
  // do INPUT_PULLUP on everything?
  for (int ii = 2; ii < NUM_DIGITAL_PINS; ++ii) {
    if (pullup[ii] != 0 ) pinMode(ii, INPUT_PULLUP);
  }
}

void loop() {
  report();
}

void report() {
  auto now = millis();                 // https://www.arduino.cc/reference/en/language/functions/time/millis/
  const typeof(now) interval = 1000;
  static typeof(now) last = -interval; // schedule to trigger immediately
  if (now - last >= interval) {        // Expired?
    last += interval;                  // Advance phase-locked with the processor clock
    //while(now - last >= interval){last += interval;} // Advance multiple times. Needed only if loop() is stupidly slow
    Serial.print(now);
    Serial.print("ms");
    for ( int ii = 0; ii < NUM_ANALOG_INPUTS; ++ii) {
      Serial.print(" ");
      Serial.print(analogRead(ii));
    }
    for ( int ii = 0; ii < NUM_DIGITAL_PINS; ++ii) {
      Serial.print(" ");
      Serial.print(digitalRead(ii));
    }
    Serial.println();
  }
}

Simulation with a couple inputs connected to buttons:

report.ino - Wokwi ESP32, STM32, Arduino Simulator